No-ip Update Script

No-IP automatic Dynamic DNS update

Tested on RouterBOARD 952Ui-5ac2nD V 6.35.4

#- Change Values in this section to match your setup -

# No-IP User account / group  info

:local noipuser "noip-username"

:local noippass "noip-password"

# Set the hostname to be updated.

:local noiphost "noiphostname.ddns.net"

# Change to the name of interface that gets the dynamic IP address

:local inetinterface "public-interface"

#------------------------------------------------------------------------------------

# No more changes need

:global previousIP

:if ([/interface get $inetinterface value-name=running]) do={

# Get the current IP on the interface

   :local currentIP [/ip address get [find interface="$inetinterface" disabled=no] address]

# Strip the net mask off the IP address

   :for i from=( [:len $currentIP] - 1) to=0 do={

       :if ( [:pick $currentIP $i] = "/") do={

           :set currentIP [:pick $currentIP 0 $i]

       }

   }

   :if ($currentIP != $previousIP) do={

       :log info "No-IP: Current IP $currentIP is not equal to previous IP, update needed"

       :set previousIP $currentIP

# The update URL. Note the "\3F" is hex for question mark (?). Required since ? is a special character in commands.

       :local url "http://dynupdate.no-ip.com/nic/update\3Fmyip=$currentIP"

       :local noiphostarray

       :set noiphostarray [:toarray $noiphost]

       :foreach host in=$noiphostarray do={

           :log info "No-IP: Sending update for $host"

           /tool fetch url=($url . "&hostname=$host") user=$noipuser password=$noippass mode=http dst-path=("no-ip_ddns_update-" . $host . ".txt")

           :log info "No-IP: Host $host updated on No-IP with IP $currentIP"

       }

   }  else={

       :log info "No-IP: Previous IP $previousIP is equal to current IP, no update needed"

   }

} else={

   :log info "No-IP: $inetinterface is not currently running, so therefore will not update."

}

-------------------------------------------------------------------------------

No-IP automatic Dynamic DNS update behind NAT

Tested in RB750Gr3 V6.39.2


#- Change Values in this section to match your setup -
:local noipuser "noip-username"
:local noippass "noip-password"
# ==========================================
# Set the hostname  to be updated.
:local noiphost "noip-hostname.ddns.net"
# ==========================================

:global previousIP


# parse the current IP result
/tool fetch mode=http address="checkip.dyndns.it" src-path="/" dst-path="/dyndns.checkip.html"
:local result [/file get dyndns.checkip.html contents]
:local resultLen [:len $result]
:local startLoc [:find $result ": " -1]
:set startLoc ($startLoc + 2)
:local endLoc [:find $result "<script" -1]
:local currentIP [:pick $result $startLoc $endLoc]
:log info "No-IP: currentIP = $currentIP";

# do update

:if ($currentIP != $previousIP) do={
       :log info "No-IP: Current IP $currentIP is not equal to previous IP, update needed"
       :set previousIP $currentIP

# The update URL. Note the "\3F" is hex for question mark (?). Required since ? is a special character in commands.
       :local url "http://dynupdate.no-ip.com/nic/update\3Fmyip=$currentIP"
       :local noiphostarray
       :set noiphostarray [:toarray $noiphost]
       :foreach host in=$noiphostarray do={
           :log info "No-IP: Sending update for $host"
           /tool fetch url=($url . "&hostname=$host") user=$noipuser password=$noippass mode=http dst-path=("no-ip_ddns_update-" . $host . ".txt")
           :log info "No-IP: Host $host updated with IP $currentIP"
       }
   }  else={
       :log info "No-IP: Previous IP $previousIP is equal to current IP, no update needed"
   }
}

Share on Facebook Share on Twitter Share on Google Plus

About Does

This is a short description in the author block about the author. You edit it by entering text in the "Biographical Info" field in the user admin panel.